INDARA and INDDS issues

[mjhaston]

I think I'm using this correctly. It's been a little while since doing a display file (subfile actually).

DDS:

A                                      CA03                  
A                                      CA06                  
A                                      CA09                  
A                                      CA12                  
A                                      INDARA

RPG:

fFIXJNT_MH cf   e             workstn    sfile( FJS : rrn )             
f                                           infds( wsds )               
f                                           indds( indicators )         


d indicators      ds                                             
d  exit                           n   overlay( indicators :  3 ) 
d  prompt                         n   overlay( indicators :  4 ) 
d  add                            n   overlay( indicators :  6 ) 
d  delete                         n   overlay( indicators :  9 ) 
d  previous                       n   overlay( indicators : 12 ) 
d  sfldsp                         n   overlay( indicators : 21 ) 
d  sflclr                         n   overlay( indicators : 22 ) 
d  sflend                         n   overlay( indicators : 23 ) 
d  sfldspctl                      n   overlay( indicators : 24 ) 
d  badFundCode                    n   overlay( indicators : 70 ) 
d  badRSSN                        n   overlay( indicators : 71 ) 
d  badName                        n   overlay( indicators : 72 ) 
d  badPension#                    n   overlay( indicators : 73 )

ISSUE:
To keep it simple when I loop through my program and hit F3 to Exit the program here are my debug values:

*IN03 = '0' (which is correct because *IN03 doesn't exist anymore)

Exit = '0' (which is wrong because I hit F3)

*INKC = '1' (which I don't care about because I don't want to use it!)

EVAL indicators                
EXIT OF INDICATORS = '0'       
PROMPT OF INDICATORS = '0'     
ADD OF INDICATORS = '0'        
DELETE OF INDICATORS = '0'     
PREVIOUS OF INDICATORS = '0'   
SFLDSP OF INDICATORS = '1'     
SFLCLR OF INDICATORS = '0'     
SFLEND OF INDICATORS = '1'     
SFLDSPCTL OF INDICATORS = '1'

[GLS400]

Re: INDARA and INDDS issues

Hi mjhaston:

Try this:

A                                      CF03(03)                  
A                                      CF06(06)                  
A                                      CF09(09)                  
A                                      CF12(12)                 
A                                      indara

I changed to CF because data is returned to the program using CF but not returned when using CA

Best of Luck
GLS

[mjhaston]

Re: INDARA and INDDS issues

That did the trick! Thanks GLS.

Interesting it seems that the (09) is what got it working. Whether I have CF or CA doesn't seem to matter, but without the (09) it doesn't do what I want.

[as400Pro]

Re: INDARA and INDDS issues

you still need to add the indicators

fCit0003AD cf   e             workstn Sfile(SelectWS:SubRR)    
f                                     infds(Info)              
f                                     indds(IndDS)             

d Info            ds                               
d Choice                369    369                 

 *  Data Structures                    
d IndDS           ds                   
d ClearSF                30     30n    
d DispSF                 31     31n    
d DispSFCtl              32     32n    
d EndSF                  33     33n    

*  Command Keys                                       
d Cmd01           c                   const(x'31')     
d Cmd02           c                   const(x'32')     
d Exit            c                   const(x'33')     
d Cmd04           c                   const(x'34')     
d Cmd05           c                   const(x'35')     
d Cmd06           c                   const(x'36')     
d Cmd07           c                   const(x'37')     
d Cmd08           c                   const(x'38')     
d Cmd09           c                   const(x'39')     
d Cmd10           c                   const(x'3A')     
d Cmd11           c                   const(x'3B')     
d Cmd12           c                   const(x'3C')     
d Cmd13           c                   const(x'B1')          
d Cmd14           c                   const(x'B2')          
d Cmd15           c                   const(x'B3')          
d Cmd16           c                   const(x'B4')          
d Cmd17           c                   const(x'B5')          
d Cmd18           c                   const(x'B6')          
d Cmd19           c                   const(x'B7')          
d Cmd20           c                   const(x'B8')          
d Cmd21           c                   const(x'B9')          
d Cmd22           c                   const(x'BA')          
d Cmd23           c                   const(x'BB')          
d Cmd24           c                   const(x'BC')          
d Select          c                   const(x'F1')          
d RollUp          c                   const(x'F5')          
d RollDown        c                   const(x'F4')          


select                                       
when      Choice = Exit                      
eval      ES = 3                             
eval      Finished = *on                     
                                             
when      Choice = Rollup                    
exsr      FillDisp                           
                                             
when      Choice = Select                    
exsr      GetParms                           
                                             
endsl