Putting data in subfile control below subfile

[fjleon]

Hey guys, simple question... I have a subfile control with data in it. Below it, i have the subfile itself, and below the subfile i want to have additional data inside the control, but i can't get it to compile Because i get error CPD7812, meaning that i can't do that.

Is there a way to do this besides putting the data below the subfile in an additional record and just writing it before doing EXFMT?

[jamief]

Re: Putting data in subfile control below subfile

you cant do that you need to create a second screen and use overlay...

[jamief]

Re: Putting data in subfile control below subfile

you could also go the other way and create a header record screen for top and
place the control on the bottom...

     A                                      DSPSIZ(24 80 *DS3)
     A                                      REF(*LIBL/LBAFREF)
     A                                      PRINT
     A                                      INDARA
     A                                      CF01
     A                                      CF02
     A                                      CF03
     A                                      CF04
     A                                      CF05
     A                                      CF06
     A                                      CF07
     A                                      CF08
     A                                      CF09
     A                                      CF10
     A                                      CF11
     A                                      CF12
     A                                      CF13
     A                                      CF14
     A                                      CF15
     A                                      CF16
     A                                      CF17
     A                                      CF18
     A                                      CF19
     A                                      CF20
     A                                      CF21
     A                                      CF22
     A                                      CF23
     A                                      CF24
     A N41                                  PAGEDOWN
     A                                      PAGEUP
     A**************************************************************************
     A          R HEAD01
     A                                      OVERLAY
     A                                  1  3DATE
     A                                      EDTCDE(Y)
     A                                  1 12TIME
     A            ATR_DACONM     1A  P
     A            H1SOLDTO       5S 0H
     A            DACONM        30A  O  1 26DSPATR(&ATR_DACONM)
     A            HDPROGRAM     10A  O  1 70
     A            C1TITLE       40A  O  2 21DSPATR(&ATR_DACONM)
     A            IPADDRESS     14A  O  2 66
     A                                  3  3'Pro#:'
     A            C1PRO#         7Y 0O  3  9EDTCDE(Z)
     A            H1CNAME       61A  O  3 18
     A            C1EMP#         5Y 0O  4  3EDTCDE(Z)
     A            C1ENAME       30A  O  4  9
     A N70                              5 42'Bundle together line items by usin-
     A                                      g'
     A                                      DSPATR(HI)
     A                                  7  3'Type options, press Enter.'
     A                                      COLOR(BLU)
     A  71                              8  5'2=Add Labor'
     A                                      COLOR(BLU)
     A                                 10  2'O'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 10  4'Gp'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 10 21'Ln#'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 10 25'Cnt'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 10 34'Qty'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 10 65'Weight'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A            C1INPUT       12A  O 10  8DSPATR(HI)
     A                                      DSPATR(UL)
     A  71                             10 76'Tag'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  6 42'like numbers in the group field ("-
     A                                      Gp")'
     A                                      DSPATR(HI)
     A**************************************************************************
     A*  Subfile number one
     A**************************************************************************
     A          R SUB01                     SFL
     A                                      SFLNXTCHG
     A            PROTECTQTY     1A  H
     A            H1PROTECT      1A  H
     A            H1HEAT        12A  H
     A            H1ITMQTY       7S 0H
     A            H1WEIGHT       7S 0H
     A            H1MAT          3A  H
     A            H1ANAL         4A  H
     A            H1SIZE         7A  H
     A            H1ITEMCODE    17A  H
     A            S1OPT          1A  B 11  2
     A  72N74N53                            DSPATR(PC)
     A N74                                  DSPATR(UL)
     A  74                                  DSPATR(PR)
     A            S1GROUP        2Y 0B 11  4EDTCDE(Z)
     A  74                                  DSPATR(PR)
     A N74                                  DSPATR(UL)
     A  75                                  DSPATR(RI)
     A  75                                  DSPATR(PC)
     A            S1INPUT       12A  B 11  8
     A  81N53N59
     A N72
     AO 73                                  DSPATR(PC)
     A  73                                  DSPATR(RI)
     A N72                                  DSPATR(UL)
     A  72                                  DSPATR(PR)
     A            S1LINE         3Y 0O 11 21EDTCDE(Z)
     A            S1CONT         2A  B 11 25
     A  53                                  DSPATR(RI)
     A  53                                  DSPATR(PC)
     A N74                                  DSPATR(UL)
     A  74                                  DSPATR(PR)
     A                                 11 28'+'
     A                                      COLOR(PNK)
     A            S1ITMQTY       7Y 0B 11 30EDTCDE(Z)
     A  80N74                               DSPATR(UL)
     A  52                                  DSPATR(RI)
     A N80
     AO 74                                  DSPATR(PR)
     A  80N81N59
     A N74
     AO 52N74                               DSPATR(PC)
     A            S1DESC1       25A  O 11 38
     A            S1WEIGHT       7Y 0O 11 64EDTCDE(Z)
     A            S1TAG          7Y 0O 11 72EDTCDE(Z)
     A            S1LABOR        1A  O 11 80
     A            S1DESC2       40A  O 12 38
     A            H1CONT        12A  O 12 25DSPATR(HI)
     A            H1ERRORS      75   H
     A**************************************************************************
     A*  Control for subfile number one
     A**************************************************************************
     A          R SUB01CTL                  SFLCTL(SUB01)
     A                                      SFLSIZ(0016)
     A                                      SFLPAG(0004)
     A                                      RTNCSRLOC(&#REC &#FLD)
     A                                      BLINK
     A                                      OVERLAY
     A                                      SFLCSRRRN(&WHERE)
     A  31                                  SFLDSP
     A  32                                  SFLDSPCTL
     A  30                                  SFLCLR
     A  33                                  SFLEND(*MORE)
     A  88                                  SFLDROP(CF23)
     A                                      SFLMODE(&MODE)
     A            SCRRN          4S 0H      SFLRCDNBR
     A            #REC          10A  H
     A            #FLD          10A  H
     A            WHERE          5S 0H
     A            MODE           1A  H
     A                                 21 19'Order Number:'
     A            INPRO#         7Y 0B 21 33EDTCDE(Z)
     A  50                                  DSPATR(RI)
     A  50
     AO 59                                  DSPATR(PC)
     A            H1PRO#         7S 0H
     A                                 21 42'Number of Labels:'
     A            C1LBLQTY       2Y 0B 21 60EDTCDE(Z)
     A  51                                  DSPATR(RI)
     A  51                                  DSPATR(PC)
     A**************************************************************************
     A*  Function Keys(01)
     A**************************************************************************
     A          R FKEY01
     A            FKEY1         79A  O 22  2COLOR(BLU)
     A            FKEY2         79A  O 23  2COLOR(BLU)
     A**************************************************************************
     A*  Subfile number two
     A**************************************************************************
     A          R SUB02                     SFL
     A                                      SFLNXTCHG
     A            H2HEAT        12A  H
     A            H2PO#          7S 0H
     A            S2HEATQTY      7Y 0B 10  7TEXT('quantity for heat')
     A                                      EDTCDE(Z)
     A                                      CHECK(RB)
     A            S2HEAT        12A  B 10 15TEXT('heat number')
     A  56                                  DSPATR(RI)
     A  56                                  DSPATR(PC)
     A            S2WEIGHT       7Y 0O 10 28EDTCDE(Z)
     A**************************************************************************
     A*  Control for subfile number two
     A**************************************************************************
     A          R SUB02CTL                  SFLCTL(SUB02)
     A                                      SFLSIZ(0016)
     A                                      SFLPAG(0010)
     A                                      RTNCSRLOC(&#REC &#FLD)
     A                                      BLINK
     A                                      OVERLAY
     A                                      SFLCSRRRN(&WHERE2)
     A  35                                  SFLDSP
     A  36                                  SFLDSPCTL
     A  34                                  SFLCLR
     A  37                                  SFLEND(*MORE)
     A                                      SFLMODE(&MODE)
     A            SCRRN2         4S 0H      SFLRCDNBR
     A            ATR_DACONM     1A  P
     A            #REC          10A  H
     A            #FLD          10A  H
     A            WHERE2         5S 0H
     A            MODE           1A  H
     A                                  1  3DATE
     A                                      EDTCDE(Y)
     A                                  1 12TIME
     A            DACONM        30A  O  1 26DSPATR(&ATR_DACONM)
     A            HDPROGRAM     10A  O  1 70
     A            C1DAY         12A  O  2  3COLOR(PNK)
     A            C1TITLE       40A  O  2 21DSPATR(&ATR_DACONM)
     A                                  4  3'Pro#:'
     A            C1PRO#         7Y 0O  4  9EDTCDE(Z)
     A            H1CNAME       61A  O  4 18
     A N70                              6  3'Type options, press Enter.'
     A                                      COLOR(BLU)
     A                                  6 34'Item:'
     A                                      COLOR(WHT)
     A            C2DESC1       30A  O  6 40COLOR(WHT)
     A                                  7  5'4=Remove'
     A                                      COLOR(BLU)
     A            C2DESC2       40A  O  7 40COLOR(WHT)
     A            C2TEXT        40A  O  8 40COLOR(PNK)
     A                                  9 15'Heat'
     A                                      COLOR(WHT)
     A                                      DSPATR(UL)
     A                                  9 11'Qty'
     A                                      COLOR(WHT)
     A                                      DSPATR(UL)
     A                                  9 29'Weight'
     A                                      COLOR(WHT)
     A                                      DSPATR(UL)
     A**************************************************************************
     A*  Function Keys(02)
     A**************************************************************************
     A          R FKEY02
     A                                 22  2'F3=Exit'
     A                                      COLOR(BLU)
     A**************************************************************************
     A*  Subfile number three  (lookup window for containers)
     A**************************************************************************
     A          R SUB03                     SFL
     A                                      SFLNXTCHG
     A            H3CGLCO        2   H
     A            S3CONT        10A  O  6  3DSPATR(PC)
     A            S3CNAME       30A  O  6 15
     A**************************************************************************
     A*  Control for subfile number three
     A**************************************************************************
     A          R SUB03CTL                  SFLCTL(SUB03)
     A                                      RTNCSRLOC(&#REC &#FLD)
     A                                      BLINK
     A                                      OVERLAY
     A                                      SFLCSRRRN(&WHERE3)
     A  39                                  SFLDSP
     A  40                                  SFLDSPCTL
     A  38                                  SFLCLR
     A  41                                  SFLEND(*MORE)
     A                                      SFLSIZ(0016)
     A                                      SFLPAG(0005)
     A                                      WINDOW(FMT3)
     A            SCRRN3         4S 0H      SFLRCDNBR
     A            #REC          10A  H
     A            #FLD          10A  H
     A            WHERE3         5S 0H
     A                                  1 13'Select & Return Container'
     A                                      DSPATR(HI)
     A N70                              3  3'Place cursor on record, Press <ENT-
     A                                      ER> to select'
     A                                      COLOR(BLU)
     A                                  5  3'Container'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  5 15'Description'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A**************************************************************************
     A          R FMT3
     A                                      WINDOW(5 10 13 50 *NOMSGLIN)
     A                                 12  2'F3=Exit'
     A                                      COLOR(BLU)
     A**************************************************************************
     A* Message subfile stuff.
     A**************************************************************************
     A          R MSGSFL
     A                                      SFL
     A                                      SFLMSGRCD(24)
     A            MSGKEY                    SFLMSGKEY
     A            PGMQ                      SFLPGMQ(10)
     A**************************************************************************
     A* Message subfile stuff
     A**************************************************************************
     A          R MSGCTL
     A                                      SFLCTL(MSGSFL)
     A                                      OVERLAY
     A                                      SFLDSP
     A                                      SFLDSPCTL
     A                                      SFLINZ
     A N03                                  SFLEND
     A                                      SFLSIZ(2)
     A                                      SFLPAG(1)
     A            PGMQ                      SFLPGMQ(10)
     A**************************************************************************
     A          R DUMMY
     A                                      ASSUME
     A                                  1  3' '
     A**************************************************************************
     A          R WIN1
     A                                      WINDOW(5 10 6 35 *NOMSGLIN)
     A N43                              2  3'The total quantity you have '
     A                                      COLOR(RED)
     A N43                              3  3'entered is less than the total'
     A                                      COLOR(RED)
     A N43                              4  3'of the original line quantity'
     A                                      COLOR(RED)
     A                                  6  2'F3=Exit'
     A                                      COLOR(BLU)
     A N43                              6 13'F10=Continue'
     A                                      COLOR(BLU)
     A**************************************************************************
     A          R WIN2
     A                                      WINDOW(5 25 10 35 *NOMSGLIN)
     A                                  2  1'Enter quantity and press <ENTER> +
     A                                       to'
     A                                      COLOR(BLU)
     A                                  3  1'print labels by break quantity for'
     A                                      COLOR(BLU)
     A                                  5  1'Line number:'
     A                                      DSPATR(HI)
     A            W2LINE#       22A  O  5 14DSPATR(HI)
     A                                  7  2'Break Quantity:'
     A            W2BREAK        3Y 0B  7 18EDTCDE(Z)
     A  54                                  DSPATR(RI)
     A  54                                  DSPATR(PC)
     A            W2ERROR       35A  O  9  1DSPATR(HI)
     A                                 10  1'F3=Exit'
     A                                      COLOR(BLU)
     A**************************************************************************
     A          R WIN3
     A                                      WINDOW(8 15 5 35 *NOMSGLIN)
     A                                  2  3'Labor Must be entered before'
     A                                      COLOR(RED)
     A                                  3  3'labels can be printed.'
     A                                      COLOR(RED)
     A                                  5  2'F3=Exit'
     A                                      COLOR(BLU)
     A**************************************************************************
     A          R WINSUB01                  SFL
     A            H1W1CONT       2A  H
     A            W1CONT        12A  O  5  1
     A            W1LOCATION    10A  B  5 14
     A**************************************************************************
     A          R WINCTL01                  SFLCTL(WINSUB01)
     A                                      SFLSIZ(0015)
     A                                      SFLPAG(0007)
     A                                      WINDOW(FMT4)
     A                                      OVERLAY
     A  43                                  SFLDSP
     A  44                                  SFLDSPCTL
     A  42                                  SFLCLR
     A  45                                  SFLEND(*MORE)
     A            SCRRN4         4S 0H      SFLRCDNBR
     A                                  1  7'Enter Locations'
     A                                      DSPATR(HI)
     A                                  4  1'Container'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  4 14'Location'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A**************************************************************************
     A          R FMT4
     A                                      WINDOW(5 40 13 28 *NOMSGLIN)
     A                                 13  2'F3=Exit'
     A                                      COLOR(BLU)
     A**************************************************************************
     A          R WIN4
     A                                      WINDOW(8 15 8 35 *NOMSGLIN)
     A                                  2  1'To continue resetting order, which'
     A                                      COLOR(RED)
     A                                  3  1'includes clearing Heat and Labor'
     A                                      COLOR(RED)
     A                                  4  1'records press <F10>.'
     A                                      COLOR(RED)
     A                                  6  1'Clear only history records :'
     A                                      DSPATR(HI)
     A            W4HISTORY      1A  B  6 30DSPATR(HI)
     A                                  8  2'F3=Exit'
     A                                      COLOR(BLU)
     A                                  8 12'F10=Continue'
     A                                      COLOR(BLU)